HB9CEM / AE7AL

Simulation Electronique pour le Radioamateur

1 Simulateurs basés sur SPICE

1.1 Berkeley SPICE

SPICE (Simulation Program with Integrated Circuit Emphasis) est un programme de simulation temporelle (avec possibilités limitées de simulations fréquentielles) écrit par l'Université californienne de Berkeley, mis dans le domaine public, et par conséquent gratuit.

SPICE requiert un netlist comme fichier d'entrée, et fournit des courbes sous forme d'un fichier ASCII. Il ne contient par conséquent aucun moyen sophistiqué d'entrée des données ou d'affichage des résultats. C'est cependant le simulateur le plus utilisé, car il sert de 'coeur' a plusieurs ensembles commerciaux, certains très chers, pour la simulation dans le domaine temporel.

1.2 MicroSim PSPICE (maintenant Orcad PSPICE)

MicroSim PSPICE est l'un de ces ensembles commerciaux, dont le principal attrait est de fournir un éditeur graphique pour l'entrée des schéma, un netlister pour la traduction du schéma, et surtout une interface de sortie appelée probe qui permet d'afficher les tensions et courants dans le circuit sous formes de très beau graphiques.

Il existe une version de démonstration de ce programme, gratuite, qui contient presque tous les avantages de la version commerciale, si ce n'est que le circuit est limité a un faible nombre d'éléments dans un même schéma. Ceci est une limitation sévère, mais permet toutefois de simuler des circuits très intéressants, en particulier pour le radioamateur.

Récemment MiscroSim a été racheté par Orcad (une entreprise initialement spécialisée dans les programmes de conception de circuits imprimés). Le status de MicroSim PSPICE (ou maintenant Orcad PSPICE) est pour le moment incertain, particulièrement en tant que programme de démonstration gratuit...!

Cependant plusieurs autres versions de SPICE sont disponibles sur le web, entre autres LT Spice (gratuit) sur le site de Linear Technology qui permet l'entrée directe de schémas sans passer par un netlist manuel. Voici donc en guise d'exemple, la simulation d'un circuit pré-amplificateur à un transistor.

1.3 Circuit d'adaptation d'impédance

a) Description du circuit

En guise d'exemple simple d'utilisation du simulateur SPICE, voici la simulation d'un circuit d'adaptation d'impédance, permettant de connecter un microphone céramique haute impédance sur une entrée basse impédance prévue pour un microphone dynamique.

Normalement un microphone céramique a une impédance de l'ordre de 50 kohms, et fournit un signal d'une amplitude jusqu'à 0,5 V (eff). Un microphone dynamique a une impédance de 200 ohms et donne un signal ne dépassant pas 100 mV (eff).

Non-seulement notre circuit devra effectuer une adaptation d'impédance, mais on désire aussi qu'il atténue le signal au niveau normal pour un microphone dynamique, soit d'un rapport de 5:1.

Le schéma ci-dessous reproduit le circuit proposé pour notre étage. Le microphone est représenté par une source alternative de 0,5 V eff, soit 0,7 V peak (Vin), en série avec une résistance de 50 kohms (R1). Pour la simulation nous choisirons une fréquence de 1 kHz, soit approximativement au milieu de la gamme qui nous intéresse, soit 300 à 3000 Hz. En un second temps, nous effectuerons une analyse en fréquence permettant de visualiser la réponse en fréquence de notre circuit.

Schema Preampli

Nous choisirons un montage à polarisation automatique, vu la faible puissance requise du circuit et le fait que ce montage doit être aussi simple que possible, étant probablement prévu pour être monté à l'intérieur du boîtier du microphone céramique.

Le transistor choisi est l'un des modèles le plus courant, soit un 2N2222, équivalent à un BC237. Sont gain (beta) est de l'ordre de 250. Ceci a son importance car le système de polarisation automatique dépend dans une bonne mesure du courant de base pour son fonctionnement. Cependant une première simulation dans ces conditions nous apprendrait que le beta du transistor est nettement inférieur à cette valeur maximale. En effet aux faibles (et forts courants) le beta du transistor diminue. Utilisons donc une valeur supposée de 120 pour nos calculs préliminaires.

La résistance R2 fournit le courant de polarisation à la base du transistor. Le montage étant un collecteur commun (émetteur follower), le collecteur est connecté directement à la ligne d'alimentation positive. La division par 5 de la tension de sortie se fera en partie par un diviseur dans le circuit d'émetteur. En effet les 0,5 V aux bornes du microphone ne sont disponibles que dans une impédance infinie. Ici l'impédance d'entrée est de l'ordre de 77 kohms, comme nous le verrons plus bas. La tension sur la base du transistor n'est alors plus que de :

0,5 · 77 / (50 + 77) = 0,3 V

La résistance de sortie sera de l'ordre de 200 ohms. Cette résistance est normalement l'impédance d'entrée de l'étage suivant. Ici une résistance de 200 ohms (R5) symbolise cette charge. La résistance de sortie de notre montage sera aussi approximativement de 200 ohms. La résistance développant la tension de sortie est choisie de 560 ohms (R4), dans le but de laisser passer la composante DC du courant d'émetteur. La valeur de cette résistance est choisie pour qu'elle donne, en combinaison avec R3, une impédance de sortie voisine de 200 ohms (loi de Thévenin).

En charge, R3 verra les 200 ohms de la charge en parallèle avec R4, soit (en négligeant l'impédance de C2) une valeur de 147 ohms. Pour obtenir la division par 3 encore requise, il faut choisir R3 de 2 fois cette valeur, (3 - 1) soit 270 ohms en valeur normalisée.

Tout ce calcul est approximatif et passablement simplifié, mais les résultats de la simulation nous permettront de nous assurer du fonctionnement du circuit et d'y apporter des modifications éventuelles.

Pour obtenir une tension de 100 mV (efficace) en sortie, soit 141 mV pk, le courant dans une résistance de 200 ohms doit être au moins de 0,7 mA (141E-3 / 200). Choisissons cependant 1,5 mA afin de pouvoir obtenir une amplitude suffisante sans distortion lors des crêtes de tension.

Ceci impose une tension de 1,4 V (approx.) sur l'émetteur, et donc 2 V sur la base. Comme la tension d'alimentation est choisie à 6 V, la résistance de base doit être de :

R = U / I = (6 - 2)/(1,5E-3 / 120) = 320 kohms

soit 330 kohms en valeur normalisée.

Pour le calcul des capacités de liaison, utilisons la fréquence la plus basse à transmettre, soit 300 Hz et considérons que la capacité doit présenter une impédance de 1/10 de celle du circuit dans lequel elle agit.

Circuit d'entrée : l'impédance d'entrée du transistor est élevée, soit la résistance de base (330 kohms) en parallèle avec l'impédance dans la base (ici RE · beta = (560 + 270) · 120 = 100 kohms), pour une résultante de 77 kohms. A ceci il faut ajouter la résistance interne du microphone de 50 kohms. Le circuit présente donc une résistance totale de 127 kohms. 1/10 de ceci donne 13 kohms, et le condensateur qui présente cette impédance à 300 Hz vaut approximativement 47 nF.

Note : le facteur de 1/10 est généralement utilisé pour des circuits nécessitant une bonne réponse en fréquence, dans le cas de la transmission au moyen d'un émetteur, une réponse en fréquence aussi 'bonne' aux fréquences basses n'est cependant pas désirable, choisissons donc un condensateur de 22 nF. La simulation fréquentielle effectuée plus bas nous permettra de vérifier que même cette valeur est encore plus que suffisante.

Dans le circuit de sortie, l'impédance est de l'ordre de 400 ohms (200 ohms de la source et 200 ohms de la charge), et le condensateur adéquat est ici de 6,8 µF.

Ces calculs effectués, il ne nous reste plus qu'à créer le netlist et procéder à la simulation du circuit pour vérifier son fonctionnement.

Tous les noeuds du circuit sont numérotés afin de procéder à la création du netlist. Le chiffre 0 est réservé à la masse. Ici 2 est l'entrée du circuit et 7 la sortie.

b) Netlist

Voici un listing du netlist en version PSPICE (Microsim) :

Adaptation d'impédance pour microphone céramique

* Ceci est le 'modèle' pour le transistor (voir  page 
* précédente pour une explication sur les modèles)

.model Q2N2222  NPN 
(Is=14.34f Xti=3 Eg=1.11 Vaf=74.03 Bf=255.9 Ne=1.307
+ Ise=14.34f Ikf=.2847 Xtb=1.5 Br=6.092 Nc=2 Isc=0 Ikr=0
+ Rc=1 Cjc=7.306p Mjc=.3416 Vjc=.75 Fc=.5 Cje=22.01p Mje=.377 
+ Vje=.75 Tr=46.91n Tf=411.1p Itf=.6 Vtf=1.7 Xtf=3 Rb=10)

* Ceci est le 'netlist' proprement dit

R1 1 2 50k      ; résistance interne du micro
C1 2 3 22n      ; Cond. de liaison d'entrée
R2 4 3 330k     ; Polarisation de base
R3 5 6 270      ; Résistance d'émetteur du haut
R4 6 0 560      ; Résistance d'émetteur du bas
C2 6 7 6.8u     ; Condensateur de liaison de sortie
R5 7 0 200      ; La résistance de charge de sortie
Q1 4 3 5 Q2N2222  ; Le transistor, dans l'ordre C B E

V1 4 0 6V       ; Alimentation de 6V

* Ceci est le générateur d'entrée, sinusoide 
* de 1 kHz, 0,5 V eff representant le microphone.

Vin 1 0 AC 0.707 SIN 0 0.707 1000 0 0

* Ceci sont des lignes de controle

.probe
.tran .125e-4 2e-3
.ac dec 10 10 3000

.END

c) Simulation temporelle

Une fois la simulation terminée, on peut obtenir une courbe des signaux d'entrée et de sortie.

Graph Time

Nous pouvons aussi obtenir des courbes pour tous les autres noeuds du circuit si nécessaire, ainsi que les différents courants. Ainsi une vérification du courant d'émetteur nous apprend que ce dernier est de 1,88 mA. Ceci indique que le beta assumé de 120 est en réalité plus élevé, peut-être de l'ordre de 150 à 200. Ceci n'est pas très important mais pourrait faire l'objet d'une autre simulation. Notons cependant que le beta d'un transistor peut varier passablement d'un élément à l'autre et que de toute façon le circuit à polarisation automatique, de par sa simplicité n'est pas un circuit très précis. Contentons nous donc du résultat obtenu.

Nous pouvons vérifier que la tension développée par le microphone à l'entrée du circuit est effectivement de 414 mV pk (curseur A1), soit quasiment 300 mV eff (division par 1,414), ce qui correspond à la valeur calculée ci-dessus.

La tension de sortie est de 119 mV pk (curseur A2), soit 85 mV eff (division par 1,414), ce qui est un peu moins que les 100 mV désirés, mais tout à fait suffisant.

Examinons maintenant la réponse en fréquence.

Graph Fresp1

Nous constatons que la réponse n'est inférieure que de 5 mV à 300 Hz par rapport à 1 kHz (Curseur A2 - Curseur A1). Ceci est trop bon. On peut aisément accepter une réponse de -3 à -6 dB à 300 Hz. On peut pour cela diminuer la valeur des deux condensateurs de liaison, et en particulier celui de sortie qui peut passer à 1 µF. Nous obtenons alors la réponse ci-dessous qui est entièrement acceptable pour un circuit destiné à la transmission de la parole (réponse de -3 dB à 300 Hz par rapport à 1 kHz).

Graph Fresp2

1.4 Conclusion

Toutes les caractéristiques du circuit pourraient être vérifiées et ajustées au moyen de simulations puis, le circuit construit, ce dernier devrait fonctionner correctement du premier coup.

Cette simulation simple a permis de mettre en évidence quelques-unes des possibilités de SPICE, en particulier dans la version de démonstration de PSPICE. Des résultats similaires peuvent être atteints au moyen d'autres versions de SPICE. Rappelons que la différence essentielle entre les différentes moutures de SPICE réside généralement dans les interfaces de pré et post-processing (entrée du schéma et affichage des résultat).


Retour Haut de page Retour Back Retour HOME (page d'accueil) Carte du Site